\start83\
\comment=Program file dated 10/22/06, 14:15
\name=RECT
\file=C:\PROGRA~1\TIEDUC~1\TI-GRA~1\RECT.TXT
ClrHome
ClrDraw
Lbl M
Menu("INTEGRATE","SETUP",S,"DRAW",D,"CALC",C,"SHOW",V,"QUIT",Q)
Lbl Q
Stop
Lbl S
Menu("SETUP","NEW Y\1\",F,"NEW A,B",A,"NEW N",N,"WINDOW",W,"MAIN",M,"SHOW",V,"QUIT",Q)
Lbl F
ClrHome
Disp "ENTER A FORMULA"
Disp "FOR Y\1\ BETWEEN"
Disp "QUOTES"
Input "NEW Y\1\?",Y\1\
Goto S
Lbl A
ClrHome
Input "GIVE START A?",A
Input "GIVE END B?",B
min(A,B)\->\A
max(A,B)\->\B
Goto S
Lbl N
ClrHome
Input "NUMBER RECTS N?",N
abs(int(N))\->\N
Goto S
Lbl W
ClrHome
Input "GIVE Xmin?",Xmin
Input "GIVE Xmax?",Xmax
min(Xmin,Xmax)\->\Xmin
max(Xmin,Xmax)\->\Xmax
Input "GIVE Ymin?",Ymin
Input "GIVE Ymax?",Ymax
min(Ymin,Ymax)\->\Ymin
max(Ymin,Ymax)\->\Ymax
Goto S
Lbl D
ClrDraw
Func
FnOff 
PlotsOff 
FnOn 1
Menu("RECT TYPE","LEFT",L,"RIGHT",R,"MID",E,"SETUP",S,"MAIN",M,"QUIT",Q)
Lbl L
ClrDraw
(B-A)/N\->\H
A\->\T
For(J,1,N,1)
Line(T,0,T,Y\1\(T))
Line(T,Y\1\(T),T+H,Y\1\(T))
Line(T+H,Y\1\(T),T+H,0)
T+H\->\T
End
sum(seq(Y\1\*H,X,A,B-H,H))\->\L
Text(2,2,"L=",L)
Pause 
Goto M
Lbl R
ClrDraw
(B-A)/N\->\H
A+H\->\T
For(J,1,N)
Line(T-H,0,T-H,Y\1\(T))
Line(T-H,Y\1\(T),T,Y\1\(T))
Line(T,Y\1\(T),T,0)
DispGraph
T+H\->\T
End
sum(seq(Y\1\*H,X,A+H,B,H))\->\R
Text(2,2,"R=",R)
DispGraph
Pause 
Goto M
Lbl E
ClrDraw
(B-A)/(2*N)\->\H
A+H\->\T
1\->\J
Lbl G
Line(T-H,0,T-H,Y\1\(T))
Line(T-H,Y\1\(T),T+H,Y\1\(T))
Line(T+H,Y\1\(T),T+H,0)
T+2*H\->\T
IS>(J,N)
Goto G
sum(seq(Y\1\*2*H,X,A+H,B-H,2*H))\->\M
Text(2,2,"M=",M)
Pause 
Goto M
Lbl C
ClrHome
Disp "CALCULATING..."
(B-A)/N\->\H
A\->\X
0\->\L
0\->\M
For(J,1,N)
L+Y\1\*H\->\L
M+Y\1\(X+0.5*H)*H\->\M
X+H\->\X
End
ClrHome
Disp "HIT ENTER AFTER"
Disp "EACH RESULT TO"
Disp "CONTINUE"
Disp " "
Disp "LHS IS ",L
Pause 
L+(Y\1\(B)-Y\1\(A))*H\->\R
Disp "RHS IS ",R
Pause 
(L+R)/2\->\T
Disp "TRAP SUM IS",T
Pause 
Disp "MID SUM IS ",M
Pause 
(2*M+T)/3\->\S
Disp "SIMP SUM IS ",S
Pause 
Goto M
Lbl V
ClrHome
Disp "A,B,N, ARE",A,B,N
Disp "PRESS ENTER"
Pause 
ClrHome
Disp "Xmin,Xmax ARE",Xmin,Xmax
Disp "PRESS ENTER"
Pause 
ClrHome
Disp "Ymin,Ymax, ARE",Ymin,Ymax
Disp "PRESS ENTER"
Pause 
Goto M
\stop83\