\start83P\
\comment=Program file dated 11/29/04, 19:56
\protected=FALSE
\name=PIV
\file=C:\MYTIDATA\TEMP\PIV.TXT
Lbl 0
ClrHome
dim([A])\->\L\1\
Menu("PIVOT","ENTER TABLEAU",E,"RATIOS",R,"PIVOT",P,"SHOW TABLEAU",S,"BACK ONE",B,"QUIT",Q)
Lbl E
[A]\->\[C]
ClrHome
Input "NUM ROWS? ",R
abs(int(R))\->\R
Input "NUM COL? ",C
abs(int(C))\->\C
{R,C}\->\dim([A])
{R,C}\->\L\1\
For(I,1,R,1)
For(J,1,C,1)
ClrHome
Disp "ENTER ROW ",I,"COL ",J
Input "VALUE? ",X
X\->\[A](I,J)
End
End
ClrHome
Pause [A]
Goto 0
Lbl Q
ClrHome
Disp "ALL DONE"
Stop
Lbl B
ClrHome
Disp "THIS ONLY WORKS"
Disp "ONCE"
[C]\->\[A]
Pause [A]\>\Frac
Goto 0
Lbl S
ClrHome
Pause [A]\>\Frac
Goto 0
Lbl R
ClrHome
Disp "FIND RATIOS FOR"
Input "WHICH COLUMN? ",C
If C>L\1\(2) or C<1
Then
Disp "BAD VALUE, TRY AGAIN":Disp "PRESS ENTER":Pause :Goto R
End
{L\1\(1),1}\->\dim([B])
For(R,1,L\1\(1),1)
If [A](R,C)\!=\0
Then
[A](R,L\1\(2))/[A](R,C)\->\[B](R,1)
Else
9999999999\->\[B](R,1)
End
End
Pause [B]
Goto 0
Lbl P
ClrHome
dim([A])\->\L\1\
Input "PIVOT COL? ",C
If C<0 or C>L\1\(2)
Then
Disp "BAD VALUE, TRY AGAIN":Disp "PRESS ENTER":Pause :Goto P
End
Lbl V
Input "PIVOT ROW ? ",R
If R<0 or R>L\1\(1)
Then
Disp "BAD VALUE, TRY AGAIN":Disp "PRESS ENTER":Pause :Goto V
End
If [A](R,C)=0
Then
Disp "PIVOT ON ZERO":Disp "PRESS ENTER":Pause :Goto P
End
Disp "PRESS ENTER"
Pause 
[A]\->\[C]
[A](R,C)\->\X
*row(1/X,[A],R)\->\[A]
For(I,1,L\1\(1),1)
If I\!=\R and [A](I,C)\!=\0
*row+(\(-)\[A](I,C),[A],R,I)\->\[A]
End
.00000001\->\X
For(I,1,L\1\(1),1)
For(J,1,L\1\(2),1)
If abs([A](I,J))<X
0\->\[A](I,J)
End
End
ClrHome
Pause [A]\>\Frac
Goto 0
\stop83P\